Tutorial Arduino : Kunci Pintu dengan RFID

Hallo Fanbot, jumpa lagi di artikel tutorial arduino,

RFID RC522 (Radio Frequency Identification) merupakan suatu teknologi yang memanfaatkan frekuensi radio sebagai pengidentifikasian terhadap suatu objek. Mempunyai 2 bagian komponen utama yaitu RFID Tag dan juga  RFID Reader. RFID Tag merupakan sebuah perangkat yang akan diidentifikasi oleh RFID reader yang dapat berupa perangkat pasif maupun aktif yang berisi suatu data atau bahkan  informasi sedangkan RFID Reader berfungsi untuk membaca data dari RFID Tag. Pembacaan data RFID Tag ini bila dihubungkan ke suatu mikrokontroler dapat dimanfaatkan sebagai sebuah mekanisme pengaman.

[lwptoc numeration=”none” title=”Daftar Isi”]

Link Library RFID : https://github.com/miguelbalboa/rfid

Skema Rangkaian

Berikut adalah skema rangkaian Kunci Pintu dengan RFID Arduino Uno yang bisa Fanbot ikuti.

BERIKUT Kunci Pintu dengan RFID Arduino Uno

Pin pada Arduino :

• Pin 2 – Pin +Buzzer
• Pin 3 – Pin Signal Relay
• Pin 4 – LED Merah
• Pin 5 – LED Hijau
• Pin 9 – Pin RST RFID Reader
• Pin 10 – Pin SDA RFID Reader
• Pin 11 – Pin MOSI RFID Reader
• Pin 12 – Pin MISO RFID Reader
• Pin 13 – Pin SCK RFID Reader

Baca Juga Cara menyimpan kode kartu pada RFID

Alat / Bahan

• Arduino 1 buah
• Breadboard 1 buah
• Sensor RFID + key tag 1 buah
• Relay 5V 1 buah
• Buzzer 1 buah
• LED 2 buah
• Resistor 220Ω 2 buah
• Solenoid 12V 1 buah
• Power Supply 12V DC 1 buah

Belajar Elektronika, Arduino, dan juga  IoT step by step dengan bantuan tangga belajar? Daftar sekarang dan dapatkan PROMO

Sketch Program

/*
    Program Kunci Pintu dengan RFID
    dibuat oleh Indobot
*/
#include <SPI.h>  //Pendeklarasian Library
#include <MFRC522.h>

#define SS_PIN 10  // Pemilihan Pin dan pendeklarasian variabel
#define RST_PIN 9
#define LED_G 5 
#define LED_R 4 
#define RELAY 3 
#define BUZZER 2 
#define ACCESS_DELAY 2000
#define DENIED_DELAY 1000
MFRC522 mfrc522(SS_PIN, RST_PIN);

void setup(){  //Pengaturan Pin dan Variabel
  Serial.begin(9600);
  SPI.begin();
  mfrc522.PCD_Init();   // memulai MFRC522
  pinMode(LED_G, OUTPUT);
  pinMode(LED_R, OUTPUT);
  pinMode(RELAY, OUTPUT);
  pinMode(BUZZER, OUTPUT);
  noTone(BUZZER);
  digitalWrite(RELAY, LOW);
  Serial.println("Letakkan kartu anda ke pembaca...");
  Serial.println();

}

void loop(){  //Perulangan Program
  if ( ! mfrc522.PICC_IsNewCardPresent())   {
    return;
  }
  if ( ! mfrc522.PICC_ReadCardSerial())   {
    return;
  }
  //Menampilkan UID ke monitor
  Serial.print("UID tag :");
  String content = "";
  byte letter;
  for (byte i = 0; i < mfrc522.uid.size; i++)
  {
    Serial.print(mfrc522.uid.uidByte[i] < 0x10 ? " 0" : " ");
    Serial.print(mfrc522.uid.uidByte[i], HEX);
    content.concat(String(mfrc522.uid.uidByte[i] < 0x10 ? " 0" : " "));
    content.concat(String(mfrc522.uid.uidByte[i], HEX));
  }
  Serial.println();
  Serial.print("Message : ");
  content.toUpperCase();
  if (content.substring(1) == "83 23 38 BB") //ganti UID 83 23 38 BB dengan UID kartu anda untuk memberi akses
  {
    Serial.println("Authorized access"); //Apabila menggunakan RFID Tag yang benar
    Serial.println();
    delay(500);
    digitalWrite(RELAY, HIGH);
    digitalWrite(LED_G, HIGH);
    delay(ACCESS_DELAY);
    digitalWrite(RELAY, LOW);
    digitalWrite(LED_G, LOW);
  }

  else   {
    Serial.println(" Access denied");  //Apabila menggunakan RFID Tag yang Salah
    digitalWrite(LED_R, HIGH);
    tone(BUZZER, 300);
    delay(DENIED_DELAY);
    digitalWrite(LED_R, LOW);
    noTone(BUZZER);
  }
}

Baca Juga Kirim Database XAMPP dengan RFID Nodemcu ESP8266

Kesimpulan

Pada projek ini RFID akan difungsikan sebagai mekanisme pengunci. Apabila menggunakan Tag yang salah pada pembacaan RFID, maka buzzer akan berbunyi dan LED merah akan menyala. Apabila menggunakan Tag yang benar, maka solenoid akan membuka kunci dan kemudian LED hijau akan menyala.